OldComp.cz

; Control word:
;  - bit 0..4 (5 bits) jump address
;  - bit 5..23 (19 bits) loop counter N
;  - bit 24..31 (8 bits) output color (set to 0 if not used)

; ============================================================================
;                    VGA output (total 28 instructions)
; ============================================================================

; Clock per pixel 'CPP':
;  VGA 640x480 ... 6
;  TV 640x480 ... 9
;  SVGA 800x600 ... 3

.program vga
.side_set 1   ; SYNC output (no opt, wait can be max. 15)
.origin 0   ; must load at zero (offsets are hardcoded in instruction stream)
.define bpp 8   ; 8 bits per pixel (number of pixels must be multiple of 4)

; ===== [3 instructions] SYNC pulse, N=delay in clock cycles - 3

public sync:
   out   x,27      side 1      ; [1] get length of SYNC pulse - 3, start of SYNC pulse
sync_loop:
   jmp   x--,sync_loop   side 1       ; [N+1] loop
public entry:
   out   pc,5      side 1      ; [1] get next control word and jump to function

; ===== [4 instructions] DARK (or color) pulse, N=delay in clock cycles - 4
; Sets dark output at time +1

public dark:
   out   x,19      side 0      ; [1] get length of delay pulse - 4, start of delay pulse
   out   pins,bpp   side 0      ; [1] dark output (or color)
dark_loop:
   jmp   x--,dark_loop   side 0      ; [N+1] loop
   out   pc,5      side 0      ; [1] get next control word and jump to function

; ===== [4 instructions] layer synchronisation (delay 8 clock cycles)
; Output first pixel at time +8 after IRQ

public irqset:
   irq   clear 4      side 0       ; [1] clear IRQ4 flag
   out   null,27      side 0      ; [1] destroy command parameter
   irq   set 4      side 0   [4]   ; [5] set IRQ flag
   out   pc,5      side 0      ; [1] get next control word and jump to function

; ===== [5 instructions] output pixels at CPP clock, N=number of pixels-2 (number of pixels must be multiple of 4)
; Output first pixel at time +1
; Missing 1 clock cycle after last pixel

public output:
   out   x,27      side 0      ; [1] get number of pixels-2
output_loop:
public extra_wait1:
   out   pins,bpp   side 0   [0]   ; [1+CPP-2] output pixels (set extra wait CPP-2)
   jmp   x--,output_loop   side 0      ; [1] loop
public extra_wait2:
   out   pins,bpp   side 0   [0]   ; [1+CPP-3] output pixels (set extra wait CPP-3)
   out   pc,5      side 0      ; [1] get next control word and jump to function

; ===== [12 instructions] layer output pixels at CPP clock (requires CPP=6 or more)
; Control word: bit 0..12 (13 bits) start delay D = clock cycles - 7 between irq and first pixel
;      bit 13..20 (8 bits) key color
;               bot 21..31 (11 bits) number of pixels - 1 (number of pixels must be multiple of 4)

.wrap_target
public layer:
   wait   0 irq 4      side 0      ; [1] wait for IRQ sync goes 0
   out   x,13      side 0      ; [1] get length of delay - 7
layer_wait:
   jmp   x--,layer_wait   side 0      ; [1] delay loop
   out   y,bpp      side 0      ; [1] get key color
   out   x,11      side 0      ; [1] get number of pixels-1
layer_loop:
   mov   isr,x      side 0      ; [1] save pixel counter into ISR
   out   x,bpp      side 0      ; [1] get output pixel
   jmp   x!=y,layer_2   side 0      ; [1] jump if pixel is not transparent
   jmp   layer_3      side 0      ; [1] jump to end of loop
layer_2:
   mov   pins,x      side 0      ; [1] output pixel to pins
layer_3:
public extra_wait3:
   mov   x,isr      side 0   [0]   ; [1+CPP-6] return pixel counter (set extra wait CPP-6)
   jmp   x--,layer_loop   side 0      ; [1] loop next pixel
.wrap